Frassle Noteset Reference

A noteset expression is a kind of short little computer program. It’s a program that frassle reads, and that describes a set of criteria for a search. Using noteset expressions, you can quickly describe a set of notes–published in or aggregated into frassle–for display using a style of your choice, or for syndication to other sites via RSS or Javascript.

Examples

feed=”http://frassle.net/Directory/rss?id=”
Shows recent notes from your feed.
responds_to( feed=”http://frassle.net/Directory/rss?id=” )
Comments on your feed.
responds_to( feed=”http://frassle.net/Directory/rss?id=” ) & not( feed=”http://frassle.net/Directory/rss?id=” )
Comments on your feed, except those authored by you.

Grammar

The grammar for a noteset expression is below. The starting rule is fullns.

        fullns     : option(s?) noteset

        option     : '!limit' '=' count
                   | '!offset' '=' count

        noteset    : selector '|' noteset
                   | selector '&' noteset
                   | selector

        selector   : '(' noteset ')'
                   | 'responds_to' '(' noteset ')'
                   | 'not' '(' noteset ')'
                   | 'permalink' comparator uri
                   | 'feed' comparator uri
                   | 'feed_id' comparator count
                   | 'cat' comparator catpath
                   | 'cat_id' comparator count
                   | 'cat_rel' comparator percentage ',' catpath
                   | 'cat_rel_id' comparator percentage ',' count
                   | 'body_word_count' comparator count
                   | 'body_length' comparator count
                   | 'contains' comparator string
                   | 'contains_any' comparator string
                   | 'title_contains' comparator string
                   | 'title_contains_any' comparator string

        comparator : '<=' | '>=' | '=' | '>' | '<'

        percentage : /(100|[0-9][0-9])%/

        uri        : /"http:\/\/[^\"]+"/i

        catpath    : /"\/?([^\"]+\/?)+"/

        count      : /[0-9]+/

        string     : /"[^\"]+"/

SEO companies on the web but we can guarantee that there are none like us